Hello World, або Мені ОС більше не потрібна, можу написати свою.

Кожен справжній програмер хоч раз у житті хоче спробувати написати свою ОСьку, але рідко хто доходить навіть до етапу написання загрузчика з диска/флешки/дискетки. Я можу похвалитись тим, що дійшов до емуляції дискетки і виводу рядка на екран віртуальної машини! Якщо хочете повторити мій “подвиг”, починайте читати даний туторіал (повторю, тут описана не ОС, а загрузчик – просто виконання невеликої порції коду на процесорі без всяких там гіндовсів та гінуксів)

Й так, що необхідно для роботи?

Намагатимусь описати крос-платформенні продукти.

1. Для роботи необхідно знання принципів машинного коду – тобто, список базових інструкцій (MOV INT OR CALL), як користуватись мітками і тп. Хоча, щоб просто запустити код – таких знань непотрібно.
2. Ассемблер – fASM. Крос-платформовий. Wiki-RUS,Wiki-ENG. (можете використати щось інше, але за результат уже не ручаюсь)
3. Віртуальна машина – BOCHS. Крос-платформова. Wiki-RUS,Wiki-ENG (можете використати щось інше, але за результат уже не ручаюсь)
4. Опціонально дизасемблер – під гінукс не знаю хорошого, але під гінду є чудесний IDA Pro.

Власне трохи теорії.

Коли комп включається, біос знаходить boot-drive, завантажує звідти перші 512 байт в пам”ять на адресу 0x7C00 і дає процесору команду jmp 0x7C00. Тобто, теоретично достатньо записати асемблерну програму в перші 512 байт boot-sectorа дискетки/диска/флешки і вона почне працювати.
Нюанси. Бут-сектор повинен мати розмір 512 байт, не більше не менше. Тобто, якщо ваша програма більша – то треба спочатку написати підпрограмку завантаження в пам”ять основної програми і передати вказівник IP на нову адресу.
Бут-сектор закінчується так: 0x55AA. Якщо цього не зробити – БІОС відмовиться працювати далі. Принциповий він….
Вся програма повинна бути записана в бінарних інструкціях процесора – заголовки і call ExitProcess тут не потрібні.
Власне і вся теорія )

hello.asm

; I won't use Ukranian, because of different encoding hells

;OK, this is simple BOOT program. All it does - puts a char on screen

org 7C00h        ; tell compiler the start adress of loaded program
                 ; allways 0x7C00 for booting programs
use16            ; Simplify all

;++++++++++++++++++++
;--   MAIN    -------
;++++++++++++++++++++

main:            ; Main program label
 mov ax,0x0000   ; Setup the Data Segment register
                 ; Location of data is DS:Offset
 mov ds,ax       ; This can not be loaded directly it has to be in two steps.
                 ; 'mov ds, 0x0000' will NOT work due to limitations on the CPU

 mov si, HelloWorld     ; Load the string into position for the procedure.
 call PutStr            ; Call/start the procedure
 jmp $                  ; jmp to current instruction, means single instr forever loop

;--------------------
;--   PutChar -------
;--------------------
PutChar:                ; Label to call procedure
 mov ah,0x0E            ; Special function: put char on text screen
 mov bh,0x00            ; Page number (Ignore for now)
 mov bl,0x07            ; Text attr: 07 = White text, black background.
 mov al,65              ; ASCII character code: char "A"
 int 0x10               ; Call the BIOS video interrupt.
 ret                    ; Return to main program

;--------------------
;--   PutStr  -------
;--------------------
PutStr:         ; Procedure label/start
 ; Set up the registers for the interrupt call
 mov ah,0x0E    ; Special function: put char on text screen
 mov bh,0x00    ; Page number (Ignore for now)
 mov bl,0x07    ;Text attr: 07 = White text, black background.

nextchar:       ; Internal label (needed to loop round for the next character)
 lodsb          ; I think of this as LOaD String Block 
                ; (Not sure if thats the real meaning though)
                ; Loads [SI] into AL and increases SI by one
 ; Check for end of string '0' 
 or al,al       ; Sets the zero flag if al = 0 
                ; (OR outputs 0's where there is a zero bit in the register)
 jz return      ; If the zero flag has been set go to the end of the procedure.
                ; Zero flag gets set when an instruction returns 0 as the answer.
 int 0x10       ; Run the BIOS video interrupt 
 jmp nextchar   ; Loop back round tothe top
return:         ; Label at the end to jump to when complete
 ret            ; Return to main program

;---------------------------
;--   Different data -------
;---------------------------
HelloWorld db 'Pruvit, danbst, tu tse zrobuv!',0   ; 0 means end character

times (512-2-($-7C00h)) db 0    ; OK, here we fill the rest of boot sector with 0
                        ; boot sector MUST be 512 bytes long....
db 055H,0AAH            ; ... and end with 0x55AA signature

image.bin

ОК, тепер у нас є файлик з кодом. Зкомпілемо його в бінарний файлик. (тут і далі використовую batch-скрипти гінди, проблем з переводом їх на гінукс надіюсь не буде )))

c:\fasm\fasm.exe hello.asm image.bin


BOCHS config.txt

Щоб БОХ правильно працював задамо йому конфігурації. Створюємо файлик config.txt в папці БОХу (насправді розширення ролі не грає, це просто для зручності гіндоус-юзерів):

floppya: 1_44= C:\fasm\EXAMPLES\Load\image.bin, status=inserted
floppyb: 1_44= a:, status=ejected
romimage: file=BIOS-bochs-latest
megs: 32
boot: floppy
vga_update_interval: 50000
keyboard_serial_delay: 250
cpu: count=1, ips=500000
mouse: enabled=0
private_colormap: enabled=0
i440fxsupport: enabled=0
clock: time0=0
log: -
panic: action=ask
error: action=report
info: action=report
debug: action=ignore

Замітка. Цей конфіг робочий для БОХу 2.4.2. Для інших версій деякі опції можуть відрізнятись. І ще – поміняйте адресу до файлу image.bin в першому рядку.

run

Для полегшення запуску вірт. машини з даним конфігом я створив батник run.bat:

bochs -q -f config.txt


Все ) Після запуску run.bat я бачу таку картинку:

Останній важливий крок

Тепер треба записати image.bin на якийсь носій і спробувати завантажитись з нього. Я це поки що робити не буду, оскільки не знаю як правильно замінювати бут-сектор флешки.

Update

Останній важливий крок

Оскільки ми переконались у тому, що наша boot-програмка працює, лишилось перевірити її на справжній платформі. У мене нема флоппі-дисководу, на диск записувати напряжно, тому я вибрав в якості носія свою флешку.
Качаєм програмку (для гінди) – MKBT
Запускаємо її
mkbt -c -x image.bin I:
image.bin – ваш бінарний образ, створений fASMом
I: – ваш флеш-драйв
Дивіться не напутайте з буквою флеш-драйва – а то при кожному включенні компа будете дивитись вашу “hello world” програмку…
Після цього при завантаженні компа затисніть F12 (або що там у вас) і виберіть флешку. У мене вона називалась USB-HDD0.

Ось тепер все!

Гінукс юзери (хоча, і не тільки вони) можуть проглянути код загрузчика GRUB stage1, оскільки в ньому знаходиться багато цікавої інформації про зчитування stage2 загрузчика з диска.

Використана “література”

1. Загрузочный CD своими руками №1
2. Загрузочный CD своими руками №2
3. Hello World Boot Loader by Daniel Rowell Faulkner
4. WeetHet – Boot from USB Flash drive